windows bat备份mysql

1. 创建如下目录结构

md D:\MySQL_Backup\bat
md D:\MySQL_Backup\sql
echo=>D:\MySQL_Backup\bat\mysql_bak.bat

D:\MySQL_Backup
├─bat       #自动化备份脚本文件
└─sql       #备份sql存储路径

2. SQL备份脚本

mysql_bak.bat

::此备份脚本，已经避免了锁表问题
@echo off

::设置备份路径
set DIR=D:\MySQL_Backup\sql
::echo %DIR%

::递归删除30天前老sql文件
forfiles /p %DIR% /s /m %DIR%\game_*.sql /d -30 /c "cmd /c del /f @path"

::获取年/月/日
set YY=%date:~0,4%
set MM=%date:~5,2%
set DD=%date:~8,2%
::echo %YY%-%MM%-%DD%

::获取时/分/秒
set timeHour=%time:~0,2%
set timeMin=%time:~3,2%
set timeSec=%time:~6,2%
::把小时中的空格替换为0
set "timeHour=%timeHour: =0%"
::echo %timeHour%%timeMin%%timeSec%


::创建当日目录-用于存放当日sql
md %DIR%\%YY%-%MM%-%DD% 2>NUL
::echo %DIR%\%YY%-%MM%-%DD%

::从配置文件筛选game_id字段作为变量,变量为%game_id%
findstr "game_id" D:\server\server\bin\xxx.cfg >D:\MySQL_Backup\bat\tmp.txt
for /f "delims== tokens=2" %%i in (D:\MySQL_Backup\bat\tmp.txt) do set id=%%i
set "id=%id: =%"
set game_id=game_%id%
::echo %game_id%

::定义mysql密码及备份文件名
set pass=password
set backfile=%game_id%_%YY%-%MM%-%DD%_%timeHour%%timeMin%%timeSec%.sql
::echo %pass% %backfile%

::备份
"C:\Program Files\MySQL\MySQL Server 5.6\bin\mysqldump" ^
--opt --single-transaction=TRUE ^
--user=root --password="%pass%" --host=127.0.0.1 ^
--protocol=tcp --port=3306 ^
--default-character-set=utf8 --single-transaction=TRUE ^
--routines -R ^
--database %game_id% > %DIR%\%YY%-%MM%-%DD%\%backfile%

::echo %DIR%\%YY%-%MM%-%DD%\%backfile%
@echo on

3. windows配置定时任务–命令行

schtasks  /create  /tn "MySQL_Backup" /tr D:\MySQL_Backup\bat\mysql_bak.bat  /sc HOURLY /mo 1  /ru "" /st 00:00:00

参数释义：

1. 创建一个名为MySQL_Backup的定时任务，从00点00分00秒开始执行mysql_bak.bat, 每小时执行一次。

2. 运行定时任务的系统账户是System账户，由 /ru 参数控制

• 本文作者： GaryWu
• 本文链接： https://garywu520.github.io/2020/07/14/windows-bat备份mysql/
• 版权声明： 本博客所有文章除特别声明外，均采用 MIT 许可协议。转载请注明出处！